module server;

import core.time;
import std.concurrency;
import std.socket;
import std.stdio;
import std.traits;
import std.typecons;


auto share(alias var) () if (is(typeof(var) == class)) {
  return cast(shared)var;
}


auto unshare(alias var) () if (is(typeof(var) == class)) {
  return cast(Unqual!(typeof(var)))var;
}


private void receiver_thread (shared Socket sks) {
  auto ssr = scoped!SocketSet();
  auto sk = unshare!sks();
  scope(exit) {
    writeln("closing socket...");
    sk.shutdown(SocketShutdown.BOTH);
    sk.close();
  }
  ubyte[1] buffer;
  writeln("receiver thread started");
  while (sk.isAlive) {
    ssr.reset();
    ssr.add(sk);
    int res = Socket.select(ssr, null, null, dur!"seconds"(3));
    if (res == 0) {
      writeln("socket timeout!");
      break;
    }
    if (res < 0) {
      writeln("select error!");
      break;
    }
    ptrdiff_t rv = sk.receive(buffer);
    if (rv == 0 || rv == Socket.ERROR) {
      if (rv == Socket.ERROR) writeln("receiving error");
      break;
    }
    writeln("received ", rv, " bytes: ", buffer[0]);
  }
  writeln("client closed connection");
}


void main () {
  TcpSocket listener = new TcpSocket(AddressFamily.INET);
  listener.setOption(SocketOptionLevel.SOCKET, SocketOption.REUSEADDR, 1);
  listener.bind(new InternetAddress("localhost", 8080));
  listener.blocking(true);
  listener.listen(0);
  for (;;) {
    try {
      Socket sk = listener.accept();
      spawn(&receiver_thread, share!sk());
    } catch (SocketAcceptException e) {
      writeln("socket accept error: ", e.msg);
    }
  }
  listener.shutdown(SocketShutdown.BOTH);
  listener.close();
}